diff --git a/libretro-fbneo/PKGBUILD b/libretro-fbneo/PKGBUILD
index e69de29..4a3ff93 100644
--- a/libretro-fbneo/PKGBUILD
+++ b/libretro-fbneo/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Alexandre Bouvier <contact@amb.tf>
+# Contributor: Oliver Jaksch <arch-aur@com-in.de>
+
+pkgname=libretro-fbneo-git
+pkgver=1.0.0.02.r1076.g10a111a19
+pkgrel=1
+pkgdesc='FinalBurn Neo multi-arcade core'
+arch=('aarch64' 'arm' 'armv6h' 'armv7h' 'i686' 'pentium4' 'x86_64')
+url='https://github.com/libretro/FBNeo'
+license=('custom')
+groups=('libretro')
+depends=('zlib' 'libretro-core-info' 'gcc-libs')
+makedepends=('git')
+conflicts=('libretro-fbneo')
+source=("$pkgname::git+$url.git")
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	sed -i 's/CFLAGS += -O2 -DNDEBUG/CFLAGS += -DNDEBUG/g' "$pkgname/src/burner/libretro/Makefile"
+	sed -i 's/CXXFLAGS += -O2 -DNDEBUG/CXXFLAGS += -DNDEBUG/g' "$pkgname/src/burner/libretro/Makefile"
+	sed -i 's/CFLAGS += -O3 -DNDEBUG -fomit-frame-pointer/CFLAGS += -DNDEBUG -fomit-frame-pointer/g' "$pkgname/src/burner/libretro/Makefile"
+	sed -i 's/CXXFLAGS += -O3 -DNDEBUG -fomit-frame-pointer/CXXFLAGS += -DNDEBUG -fomit-frame-pointer/g' "$pkgname/src/burner/libretro/Makefile"
+}
+
+build() {
+	make -C "$pkgname/src/burner/libretro" generate-files
+	if [ "$CARCH" = 'x86_64' ]; then
+		make USE_X64_DRC=1 EXTERNAL_ZLIB=1 -C "$pkgname/src/burner/libretro"
+	else
+		make EXTERNAL_ZLIB=1 -C "$pkgname/src/burner/libretro"
+	fi
+}
+
+package() {
+	install -Dm644 "$pkgname/src/burner/libretro/fbneo_libretro.so" "$pkgdir/usr/lib/libretro"
+	install -Dm644 "$pkgname/src/license.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}